Замена главной иконки исполняемого файла

11.04.2018 | Категория: Образ мышления: Assembler | Автор: ManHunter

Замена главной иконки исполняемого файла

Продолжаем тему иконок. Сегодня разберем способ, как можно заменить главную иконку приложения на другую. Зачем это надо? Например, может возникнуть потребность заменить иконку в неком исполняемом файле на иконку документа Word или PDF ;) Или надо перенести в свежесобранный патч иконку из обрабатываемой им софтины. Или, как в моем случае, вам не нравится оригинальная иконка какого-нибудь приложения и вы хотите поменять ее на что-нибудь свое. Применение этой технологии вы определите для себя сами. Как говорила Масяня в одноименном мультике: "Мое дело подарок подарить, а ты уж думай, что с этой хренью делать".

Исходное положение. Есть файл с иконкой или мультииконкой и есть целевой исполняемый файл с одной или несколькими иконками в ресурсах. Задача заключается в переносе иконок из файла в ресурсы.

Для работы потребуются две структуры, описывающие внутренности группы иконок в ресурсах и в файле с иконками. FASM про них, естественно, ничего не знает.

Code (Assembler) : Убрать нумерацию

; Структуры для работы с иконками в группе
struct ICONDIR
idReserved dw ? ; Зарезервировано (должно быть 0)
idType dw ? ; Тип ресурса (1 для иконок)
idCount dw ? ; Количество изображений в иконке
ends
struct GRPICONDIRENTRY
bWidth db ? ; Ширина изображения в пикселах
bHeight db ? ; Высота изображения в пикселах
bColorCount db ? ; Количество цветов
bReserved db ? ; Зарезервировано
wPlanes dw ? ; Зарезервировано
wBitCount dw ? ; Зарезервировано
dwBytesInRes dd ? ; Размер данных изображения
nID dw ? ; ID иконки в ресурсах
ends

Следующий блок - константы и переменные из сегмента данных. Они прокомментированы, но использование подробно будет описано в соответствующих блоках кода.

Code (Assembler) : Убрать нумерацию

; Максимально допустимое количество иконок в группе
MAX_ICONS = 128
; Целевой файл
szTarget db 'change_target.exe',0
; Файл с иконками
szIcon db 'change_source.ico',0
pMem dd ? ; Память для файла с иконками
dFIconNum dd ? ; Количество иконок в файле
hTarget dd ? ; Хэндл загруженного целевого файла
hResource dd ? ; Хэндл обновляемых ресурсов целевого файла
hGroup dd ? ; Хэндл и память для группы иконок
pGroup dd ?
dGIconNum dd ? ; Количество иконок в группе
dID dd ? ; ID обновляемой иконки
dDiscard dd ? ; Флаг применения сделанных изменений
; Массив с ID иконок в группе
IconsID rw MAX_ICONS
iid_len = $-IconsID
; Заготовка для RT_GROUP_ICON
res_head ICONDIR
res_data rb (sizeof.GRPICONDIRENTRY*MAX_ICONS)
res_len = $-res_head

Начнем с загрузки файла иконки в память и простенькой проверки на корректность данных внутри этого файла. Подразумевается, что файл на диске есть и доступен для чтения.

Code (Assembler) : Убрать нумерацию

; Загрузить в память файл иконки
invoke CreateFile,szIcon,GENERIC_READ,0,0,OPEN_EXISTING,0,0
cmp eax,-1
je loc_exit
mov ebx,eax
invoke GetFileSize,ebx,NULL
mov esi,eax
invoke GlobalAlloc,GMEM_FIXED,eax
or eax,eax
jz loc_exit
mov [pMem],eax
invoke _lread,ebx,eax,esi
invoke CloseHandle,ebx
; Проверить корректность файла с иконками
mov esi,[pMem]
cmp word [esi+ICONDIR.idReserved],0
jne loc_free_mem
cmp word [esi+ICONDIR.idType],1
jne loc_free_mem
; Получить количество иконок в файле
movzx eax,word [esi+ICONDIR.idCount]
or eax,eax
jz loc_free_mem
; Установленное нами максимальное количество иконок в файле
cmp eax,MAX_ICONS
ja loc_free_mem
; Сохранить количество иконок
mov [dFIconNum],eax
...
...
...
loc_free_mem:
; Очистить память файла иконки
invoke GlobalFree,[pMem]

Внутренний формат файла с иконками подробно описан в официальной документации. Быстрая проверка заключается в том, что значение idType в структуре ICONDIR должно быть 1, idReserved всегда 0, а количество иконок в файле idCount должно быть ненулевым. Теоретически, количество иконок может быть ограничено только максимальным значением WORD, то есть 65535. Официально установленной или рекомендованной верхней границы по количеству иконок я нигде в документации не нашел. Но, так как у нас будет резервироваться память на основании этого значения, для внутреннего использования примем максимальное значение в 128 иконок. На практике я ни разу не встречал мультииконки с таким количеством изображений, так что этого значения должно хватить с лихвой. Соответственно, значение idCount будет сравниваться еще и с установленной верхней границей. При невыполнении любого из этих условий файл иконки признается негодным для работы. Конечно, можно еще дополнительно заморочиться и проверить корректность всех структур ICONDIRENTRY, следующих за заголовком, но в рамках статьи я этого делать не буду. Вы же, для обеспечения максимальной отказоустойчивости ваших приложений, имейте это в виду.

Переходим к обработке целевого файла. Его надо загрузить в память функцией LoadLibrary и параллельно с этим подготовить ресурсы для редактирования при помощи функции BeginUpdateResource. Если замена иконок пройдет без ошибок, то останется только выгрузить файл из памяти, а изменения в ресурсах зафиксировать функцией EndUpdateResource.

Code (Assembler) : Убрать нумерацию

; Сохранять изменения в ресурсах
mov [dDiscard],FALSE
; Загрузить целевой файл в память
invoke LoadLibrary,szTarget
or eax,eax
jz loc_free_mem
; Хэндл загруженного целевого файла
mov [hTarget],eax
; Начать обновление ресурсов
invoke BeginUpdateResource,szTarget,FALSE
or eax,eax
jz loc_unload
; Хэндл обновляемых ресурсов целевого файла
mov [hResource],eax
; Найти и обработать первую группу иконок в ресурсах
invoke EnumResourceNames,[hTarget],RT_GROUP_ICON,\
EnumResNameProc,NULL
; Выгрузить файл из памяти
invoke FreeLibrary,[hTarget]
; Применить изменения в ресурсах, но только если не было ошибок
invoke EndUpdateResource,[hResource],[dDiscard]
jmp loc_free_mem
loc_unload:
; Выгрузить файл из памяти
invoke FreeLibrary,[hTarget]

При кажущейся простоте работы с ресурсами, приходится учитывать несколько важных моментов. Надо обрабатывать первый по счету ресурс типа RT_GROUP_ICON, но просто так по какому-то фиксированному имени его не загрузить, так как ресурс может иметь как цифровой индекс, так и строковый. Поэтому придется воспользоваться функцией перебора всех ресурсов нужного типа EnumResourceNames.

Code (Assembler) : Убрать нумерацию

;---------------------------------------------------
; Поиск первой группы иконок
;---------------------------------------------------
proc EnumResNameProc hModule:DWORD, lpszType:DWORD, lpszName:DWORD, lParam:DWORD
pusha
; Обновить данные для всех языков
invoke EnumResourceLanguages,[hModule],[lpszType],[lpszName],\
EnumResLangProc,NULL
or eax,eax
jnz @f
; Языков не найдено, возможно, битый ресурс
mov [dDiscard],TRUE
@@:
popa
; Обрабатываем только первую группу иконок
mov eax,FALSE
ret
endp

В этой маленькой callback-функции тоже не все так просто. Ресурсы в исполняемых файлах могут быть с привязкой к какому-либо одному языку, а также разделены по нескольким языкам. Теоретически, для каждого языка в файле может быть своя группа иконок, да еще и количество иконок в каждой языковой группе может отличаться. Другой вопрос, что на практике для главных иконок обычно создается не более одной группы, но при любом раскладе все равно придется задействовать функцию EnumResourceLanguages и перебрать поочередно все языки, так как используемый язык ресурсов мы пока не знаем. Если ни одного языка не найдено, значит ресурсы повреждены и модифицировать файл нельзя.

Вся основная работа с ресурсами выполняется в callback-функции перебора языков. Код подробно прокомментирован, но я еще поясню все происходящее словами.

Code (Assembler) : Убрать нумерацию

;---------------------------------------------------
; Обработка всех языков для этой группы иконок
;---------------------------------------------------
proc EnumResLangProc hModule:DWORD, lpszType:DWORD, lpszName:DWORD,\
wIDLanguage:DWORD, lParam:DWORD
pusha
; Очистить память для новой группы
invoke RtlZeroMemory,res_head,res_len
invoke RtlZeroMemory,IconsID,iid_len
; Найти группу иконок в ресурсах
invoke FindResourceEx,[hModule],[lpszType],[lpszName],[wIDLanguage]
or eax,eax
jnz @f
; Группа не найдена, файл не обновлять
mov [dDiscard],TRUE
jmp .loc_next
@@:
mov [hGroup],eax
; Загрузить группу иконок
invoke LoadResource,[hModule],[hGroup]
or eax,eax
jnz @f
; Загрузить не удалось, файл не обновлять
mov [dDiscard],TRUE
jmp .loc_next
@@:
; Получить указатель на начало данных в памяти
invoke LockResource,eax
mov [pGroup],eax
; Проверить корректность группы
mov esi,[pGroup]
cmp word [esi+ICONDIR.idType],1
je @f
; Тип ресурса не соответствует группе иконок
mov [dDiscard],TRUE
jmp .loc_next
@@:
; Получить количество иконок в группе
movzx eax,word [esi+ICONDIR.idCount]
or eax,eax
jnz @f
; Количество иконок нулевое
mov [dDiscard],TRUE
jmp .loc_next
@@:
cmp eax,MAX_ICONS
jbe @f
; Количество иконок превышает максимально допустимое
mov [dDiscard],TRUE
jmp .loc_next
@@:
mov [dGIconNum],eax
; Сохранить ID отдельных иконок из группы
add esi,sizeof.ICONDIR
mov edi,IconsID
mov ecx,[dGIconNum]
@@:
add esi,12
movsw
loop @b
; Скопировать заголовок иконок из файла в группу
mov esi,[pMem]
mov edi,res_head
mov ecx,sizeof.ICONDIR
rep movsb
xor ebx,ebx
.process_icon:
; Скопировать параметры иконок из файла в группу
; bWidth, bHeight, bColorCount, bReserved
movsd
; wPlanes, wBitCount
movsd
; dwBytesInRes
lodsd
; Размер данных иконки
mov edx,eax
stosd
; ID иконки из списка ресурсов
movzx ecx,word [IconsID+ebx*2]
or ecx,ecx
jnz .id_ok
; В ресурсах иконки закончились, но в файле еще есть
push edx
; Найти первый свободный ID для новой иконки
mov ecx,[dID]
.scan_res:
inc ecx
push ecx
invoke FindResourceEx,[hModule],RT_ICON,ecx,[wIDLanguage]
pop ecx
or eax,eax
jnz .scan_res
pop edx
.id_ok:
; Записать ID иконки в группу
mov eax,ecx
mov [dID],eax
stosw
; Смещение данных относительно начала файла иконки
lodsd
add eax,[pMem]
; Обновить ресурсы
invoke UpdateResource,[hResource],RT_ICON,ecx,\
[wIDLanguage],eax,edx
or eax,eax
jnz @f
; Заменить иконку не удалось
mov [dDiscard],TRUE
jmp .loc_next
@@:
; Следующая иконка из файла
inc ebx
cmp ebx,[dFIconNum]
jb .process_icon
; Удалить все оставшиеся в группе иконки
.delete_icons:
movzx eax,[IconsID+ebx*2]
or eax,eax
jz .delete_icons_done
invoke UpdateResource,[hResource],RT_ICON,eax,[wIDLanguage],0,0
or eax,eax
jnz @f
; Удалить иконку не удалось
mov [dDiscard],TRUE
jmp .loc_next
@@:
inc ebx
jmp .delete_icons
.delete_icons_done:
; Вычислить размер группы иконок
mov eax,[dFIconNum]
mov ecx,sizeof.GRPICONDIRENTRY
mul ecx
add eax,sizeof.ICONDIR
; Обновить группу иконок в файле
invoke UpdateResource,[hResource],RT_GROUP_ICON,[lpszName],\
[wIDLanguage],res_head,eax
or eax,eax
jnz .loc_next
; Обновить группу иконок не удалось
mov [dDiscard],TRUE
.loc_next:
popa
mov eax,TRUE
; Если есть хоть одна ошибка, то больше ничего не обрабатываем
cmp [dDiscard],TRUE
jne @f
mov eax,FALSE
@@:
ret
endp

Сперва в память загружается описатель группы иконок и проверяется на соответствие формату. Ситуация, когда тип отличается, маловероятная, но тем не менее возможная. Затем из него в отдельный массив переносятся все идентификаторы отдельных иконок, которые находятся в этой группе. Следующим шагом заполняется структура новой группы иконок на основании загруженного файла с иконками. При этом, с помощью функции UpdateResource иконки в ресурсах последовательно заменяются на иконки из файла. В отличие от традиционных редакторов ресурсов типа eXeScope и Restorator, не требуется, чтобы размер новой иконки в точности соответствовал размеру иконки в ресурсах. Если количество иконок в ресурсах совпадает с количеством иконок в файле, то они просто будут заменены на новые. Но может возникнуть ситуация, когда в ресурсах иконки уже закончились, а в файле еще нет. В этом случае вычисляется первый не занятый ID иконки и в ресурсы добавляется новая иконка. Кроме того, может возникнуть противоположная ситуация, когда в файле больше нет иконок, а в ресурсах еще остались. В этом случае все лишние иконки будут удалены из ресурсов. Вся прелесть работы с функцией UpdateResource в том, нам не надо задумываться о таких сложных вещах, как изменение размера ресурсов при модификации, добавлении или удалении иконок, всю грязную работу система выполняет самостоятельно. Когда обработка иконок будет завершена, в ресурсах надо будет обновить группу иконок, заменив ее на созданную группу. При любой ошибке взводится флаг, что ресурсы в исполняемом файле обновлять не надо, и дальнейшая обработка прекращается. Если ошибок нет, то сделанные изменения фиксируются при помощи функции EndUpdateResource.

В приложении пример программы с исходным текстом, которая заменяет иконку в ресурсах другого исполняемого файла на иконку из файла.

Пример программы с исходным текстом (FASM)

Change.Icon.Demo.zip (12,199 bytes)

Просмотров: 2025 | Комментариев: 2

Метки: Assembler, иконки

Внимание! Статья опубликована больше года назад, информация могла устареть!

Добавить комментарий

Заполните форму для добавления комментария

Если программист в девять утра уже на работе, значит он там же и ночевал

Главная страница Web-мастеру и не только Образ мышления: Assembler Мои программы Software Темная сторона Силы Обзоры техники А еще я туда ем! Жизнь в оффлайне Всякая всячина

Карта сайта Ссылки Обратная связь Правила сайта Настройки сайта RSS-канал

Материалы, опубликованные на этом сайте, не рекомендуются к просмотру лицам в возрасте до 16 лет без присутствия взрослых.

Метки статей

Свернуть

Вам помог этот сайт?

Поблагодарили 35,699 раз

День памяти крымчаков и евреев Крыма – жертв нацизма

Международный день танго

Нашли на сайте орфографическую ошибку? Выделите ее мышкой и нажмите

Ctrl

Enter

Буду очень благодарен, если размеcтите мою кнопочку:

<a href="https://www.manhunter.ru" target="_blank"><img src="https://www.manhunter.ru/images/button.gif" alt="Личный блог ManHunter'а" title="Личный блог ManHunter'а" width="88" height="31" /></a>

$Яндекс тИЦ: {YANDEX_TIC}$

Яндекс ИКС: 360

Сейчас я слушаю

---

- автообновление

Powered by PCL's Speckled Band Engine 0.2 RC3
© ManHunter / PCL, 2008-2024
При использовании материалов ссылка на сайт обязательна
Время генерации: 0.07 сек. / MySQL: 2 (0.0055 сек.) / Память: 4.5 Mb

	2024 - ДЕКАБРЬ
Пн	Вт	Ср	Чт	Пт	Сб	Вс
						1
2	3	4	5	6	7	8
9	10	11	12	13	14	15
16	17	18	19	20	21	22
23	24	25	26	27	28	29
30	31

Замена главной иконки исполняемого файла

Комментарии

Добавить комментарий