Извлечение главной иконки из исполняемого файла

18.05.2018 | Категория: Образ мышления: Assembler | Автор: ManHunter

Извлечение главной иконки из исполняемого файла

В комментариях к недавней статье про замену главной иконки исполняемого файла задали очень правильный вопрос: как извлечь иконки из ресурсов исполняемого файла? Сегодня я постараюсь подробно рассказать вам, как это делается.

Начнем с описания структур, необходимых для работы с иконками. Они уже были в прошлых статьях. Так как мы будем использовать ресурсы и файлы иконок, нам понадобятся они все.

Code (Assembler) : Убрать нумерацию

; Структуры для работы с иконками в группе
struct ICONDIR
idReserved dw ? ; Зарезервировано (должно быть 0)
idType dw ? ; Тип ресурса (1 для иконок)
idCount dw ? ; Количество изображений в иконке
ends
struct GRPICONDIRENTRY
bWidth db ? ; Ширина изображения в пикселах
bHeight db ? ; Высота изображения в пикселах
bColorCount db ? ; Количество цветов
bReserved db ? ; Зарезервировано
wPlanes dw ? ; Зарезервировано
wBitCount dw ? ; Зарезервировано
dwBytesInRes dd ? ; Размер данных изображения
nID dw ? ; ID иконки в ресурсах
ends
struct ICONDIRENTRY
bWidth db ? ; Ширина изображения в пикселах
bHeight db ? ; Высота изображения в пикселах
bColorCount db ? ; Количество цветов
bReserved db ? ; Зарезервировано
wPlanes dw ? ; Зарезервировано
wBitCount dw ? ; Зарезервировано
dwBytesInRes dd ? ; Размер данных изображения
dwImageOffset dd ? ; Смещение данных относительно начала файла
ends

Начальные действия похожи на действия при замене иконок. Сперва загружаем исходный исполняемый файл в память перебираем в нем все ресурсы с типом RT_GROUP_ICON, то есть группы иконок. После обработки файл из памяти выгружается. Тут проблем быть не должно.

Code (Assembler) : Убрать нумерацию

; Загрузить исходный файл в память
invoke LoadLibrary,szSource
or eax,eax
jz loc_exit
; Хэндл загруженного исходного файла
mov [hSource],eax
; Найти и обработать первую группу иконок в ресурсах
invoke EnumResourceNames,[hSource],RT_GROUP_ICON,EnumResNameProc,NULL
; Выгрузить файл из памяти
invoke FreeLibrary,[hSource]
loc_exit:

Для каждой найденной группы иконок надо обработать доступные языки. Как я уже писал в предыдущей статье, для каждого языка в ресурсах может быть своя группа иконок. Поэтому надо перебрать их поочередно, но извлекать иконки будем все равно только из первого доступного.

Code (Assembler) : Убрать нумерацию

proc EnumResNameProc hModule:DWORD, lpszType:DWORD, lpszName:DWORD, lParam:DWORD
pusha
invoke EnumResourceLanguages,[hModule],[lpszType],[lpszName],\
EnumResLangProc,NULL
popa
; Обрабатываем только первую группу иконок
mov eax,FALSE
ret
endp

Когда мы получим доступ к группе иконок в ресурсах, у нас будет два варианта их извлечения: записать каждую иконку в отдельный файл или сформировать единый файл мультииконки, куда будут записаны все иконки из ресурсов. Начнем с самого простого - извлечение иконок в отдельные файлы. Для этого нам в сегменте данных понадобятся следующие переменные:

Code (Assembler) : Убрать нумерацию

; Шаблон имени файла для отдельных иконок
mask db 'extract_single_%ux%u_%ubit.ico',0
szFile rb MAX_PATH
dGIconNum dd ? ; Количество иконок в группе
hResource dd ? ; Хэндл иконки
iconX dd ? ; Размер иконки X
iconY dd ? ; Размер иконки Y
iconB dd ? ; Глубина цвета иконки
dSize dd ? ; Размер данных изображения иконки
lpRes dd ? ; Указатель на данные изображения иконки
; Заголовок файла иконки
res_head ICONDIR
res_data ICONDIRENTRY
res_len = $-res_head

Для большей наглядности каждая отдельная иконка будет сохраняться в файл, в имени которого содержится размер иконки и глубина цвета. Осталось все это воплотить в коде:

Code (Assembler) : Убрать нумерацию

proc EnumResLangProc hModule:DWORD, lpszType:DWORD, lpszName:DWORD,\
wIDLanguage:DWORD, lParam:DWORD
pusha
; Найти группу иконок в ресурсах
invoke FindResourceEx,[hModule],[lpszType],[lpszName],[wIDLanguage]
or eax,eax
; Группа не найдена
jz .loc_next
; Загрузить группу иконок
invoke LoadResource,[hModule],eax
or eax,eax
; Загрузить не удалось
jz .loc_next
; Получить указатель на начало данных в памяти
invoke LockResource,eax
; Проверить корректность группы
mov esi,eax
cmp word [esi+ICONDIR.idType],1
jne .loc_next
; Получить количество иконок в группе
movzx eax,word [esi+ICONDIR.idCount]
or eax,eax
; Количество иконок нулевое
jz .loc_next
mov [dGIconNum],eax
xor ebx,ebx
; Обработать отдельные иконки из группы
add esi,sizeof.ICONDIR
.loc_process_icon:
; Очистить память для новой иконки
invoke RtlZeroMemory,res_head,res_len
; Идентификатор иконки в ресурсах
movzx eax,word[esi+GRPICONDIRENTRY.nID]
; Найти ресурс иконки
invoke FindResourceEx,[hModule],RT_ICON,eax,[wIDLanguage]
or eax,eax
jz .loc_next_icon
mov [hResource],eax
; Получить размер данных
invoke SizeofResource,[hModule],eax
or eax,eax
jz .loc_next_icon
mov [dSize],eax
; Загрузить ресурс
invoke LoadResource,[hModule],[hResource]
or eax,eax
jz .loc_next_icon
; Получить указатель на начало данных в памяти
invoke LockResource,eax
mov [lpRes],eax
; Сформировать заголовок файла для одиночной иконки
mov [res_head.idReserved],0
mov [res_head.idType],1
mov [res_head.idCount],1
; Сформировать запись ICONDIRENTRY для одиночной иконки
movzx eax,byte [esi+GRPICONDIRENTRY.bWidth]
mov [iconX],eax
mov [res_data.bWidth],al
movzx eax,byte [esi+GRPICONDIRENTRY.bHeight]
mov [iconY],eax
mov [res_data.bHeight],al
movzx eax,byte [esi+GRPICONDIRENTRY.bColorCount]
mov [res_data.bColorCount],al
mov [res_data.bReserved],0
mov ax,[esi+GRPICONDIRENTRY.wPlanes]
mov [res_data.wPlanes],ax
movzx eax,word [esi+GRPICONDIRENTRY.wBitCount]
mov [iconB],eax
mov [res_data.wBitCount],ax
; Размер данных изображения
mov eax,[dSize]
mov [res_data.dwBytesInRes],eax
; Смещение данных сразу после заголовка файла
mov [res_data.dwImageOffset],sizeof.ICONDIR+sizeof.ICONDIRENTRY
; Для иконки в PNG-формате размеры X и Y будут нулевыми
cmp [iconX],0
jne @f
mov eax,[lpRes]
; Это точно PNG?
cmp dword [eax],474E5089h
jne .loc_next_icon
cmp dword [eax+0Ch],'IHDR'
jne .loc_next_icon
; Размер и глубина цвета из заголовка PNG
mov edx,[eax+10h]
bswap edx
mov [iconX],edx
mov edx,[eax+14h]
bswap edx
mov [iconY],edx
movzx edx,byte [eax+18h]
mov [iconB],edx
@@:
; Сформировать имя файла
invoke wsprintf,szFile,mask,[iconX],[iconY],[iconB]
add esp,20
.loc_write_file:
; Записать иконку в файл
push ebx
invoke _lcreat,szFile,0
mov ebx,eax
; Записать заголовок иконки
invoke _lwrite,ebx,res_head,sizeof.ICONDIR+sizeof.ICONDIRENTRY
; Записать данные из ресурсов
invoke _lwrite,ebx,[lpRes],[dSize]
invoke _lclose,ebx
pop ebx
.loc_next_icon:
; Следующая иконка в группе
add esi,sizeof.GRPICONDIRENTRY
inc ebx
cmp ebx,[dGIconNum]
jb .loc_process_icon
.loc_next:
popa
mov eax,FALSE
ret
endp

Теперь поясню словами, что тут происходит. Сперва группа иконок, извлеченная из ресурсов, проверяется на корректность. То есть idType в структуре ICONDIR должен равняться 1, а количество иконок idCount должно быть не меньше 1. Максимальное количество иконок в группе не проверяется, так как никакой памяти под них заранее не резервируется. Дальше поочередно из группы читается структура GRPICONDIRENTRY для каждой иконки, определяется размер графических данных иконки и их местонахождение в памяти. Все недоступные или поврежденные ресурсы игнорируются. Затем формируется заголовок файла иконки ICONDIR, информация из GRPICONDIRENTRY дублируется в ICONDIRENTRY и полный заголовок записывается в файл иконки, после чего к нему дописываются графические данные. Поскольку мы формируем имя файла иконки с учетом размеров и глубины цвета иконки, надо учитывать симтуации, когда в качестве иконки используется изображение в формате PNG размером 256х256 пикселов. В этом случае поля структур bWidth и bHeight будут нулевыми. Выполняется дополнительная проверка, и для PNG-файлов информация о размере изображения извлекается напрямую из файла. Если интересно, откуда что берется, подробности о внутреннем формате PNG вы можете почитать в официальной документации.

Второй, более сложный случай - извлечение всех доступных иконок из главной группы иконок исполняемого файла в единый файл мультииконки. В сегменте данных понадобятся следующие переменные:

Code (Assembler) : Убрать нумерацию

; Максимально допустимое количество иконок в группе
MAX_ICONS = 128
; Файл с иконками
szFile db 'extract_multi.ico',0
hFile dd ?
dGIconNum dd ? ; Количество иконок в группе
hResource dd ? ; Хэндл иконки
pGroup dd ? ; Указатель на группу иконок в памяти
dOffset dd ? ; Смещение данных от начала файла иконки
dSize dd ? ; Размер данных изображения иконки
lpRes dd ? ; Указатель на данные изображения иконки
; Заголовок файла иконок
res_head ICONDIR
res_data rb (sizeof.ICONDIRENTRY*MAX_ICONS)
res_len = $-res_head

Код получился более объемный, но это сделано для повышения его отказоустойчивости при обработке поврежденных или недоступных ресурсов.

Code (Assembler) : Убрать нумерацию

proc EnumResLangProc hModule:DWORD, lpszType:DWORD, lpszName:DWORD,\
wIDLanguage:DWORD, lParam:DWORD
pusha
; Найти группу иконок в ресурсах
invoke FindResourceEx,[hModule],[lpszType],[lpszName],[wIDLanguage]
or eax,eax
; Группа не найдена
jz .loc_next
; Загрузить группу иконок
invoke LoadResource,[hModule],eax
or eax,eax
; Загрузить не удалось
jz .loc_next
; Получить указатель на начало данных в памяти
invoke LockResource,eax
mov esi,eax
mov [pGroup],eax
; Проверить корректность группы
cmp word [esi+ICONDIR.idType],1
jne .loc_next
; Получить количество иконок в группе
movzx eax,word [esi+ICONDIR.idCount]
or eax,eax
; Количество иконок нулевое
jz .loc_next
cmp eax,MAX_ICONS
; Количество иконок превышает максимально допустимое
ja .loc_next
mov [dGIconNum],eax
; Обработать отдельные иконки из группы
add esi,sizeof.ICONDIR
; Очистить память для иконки
invoke RtlZeroMemory,res_head,res_len
; Сформировать заголовок файла иконки
mov [res_head.idReserved],0
mov [res_head.idType],1
mov [res_head.idCount],0
mov edi,res_data
.loc_process_icon:
; Сформировать запись ICONDIRENTRY для одной иконки
movzx eax,word[esi+GRPICONDIRENTRY.nID]
; Найти ресурс иконки
invoke FindResourceEx,[hModule],RT_ICON,eax,[wIDLanguage]
or eax,eax
jz .loc_next_icon
mov [hResource],eax
; Получить размер данных
invoke SizeofResource,[hModule],eax
or eax,eax
jz .loc_next_icon
mov [dSize],eax
; Загрузить ресурс
invoke LoadResource,[hModule],[hResource]
or eax,eax
jz .loc_next_icon
; Сформировать запись ICONDIRENTRY для одной иконки
mov al,[esi+GRPICONDIRENTRY.bWidth]
mov [edi+ICONDIRENTRY.bWidth],al
mov al,[esi+GRPICONDIRENTRY.bHeight]
mov [edi+ICONDIRENTRY.bHeight],al
mov al,[esi+GRPICONDIRENTRY.bColorCount]
mov [edi+ICONDIRENTRY.bColorCount],al
mov ax,[esi+GRPICONDIRENTRY.wBitCount]
mov [edi+ICONDIRENTRY.wBitCount],ax
mov [edi+ICONDIRENTRY.bReserved],0
mov ax,[esi+GRPICONDIRENTRY.wPlanes]
mov [edi+ICONDIRENTRY.wPlanes],ax
mov eax,[dOffset]
mov [edi+ICONDIRENTRY.dwImageOffset],eax
mov eax,[dSize]
mov [edi+ICONDIRENTRY.dwBytesInRes],eax
add [dOffset],eax
; Увеличить количество иконок в заголовке файла
inc [res_head.idCount]
; Следующая структура ICONDIRENTRY
add edi,sizeof.ICONDIRENTRY
.loc_next_icon:
; Следующая иконка в группе
add esi,sizeof.GRPICONDIRENTRY
inc ebx
cmp ebx,[dGIconNum]
jb .loc_process_icon
; Хоть одна иконка нашлась?
cmp [res_head.idCount],0
je .loc_next
; Создать файл иконки
invoke _lcreat,szFile,0
mov [hFile],eax
; Вычислить размер получившегося заголовка для мульти-иконки
movzx eax,word [res_head.idCount]
xor edx,edx
mov ecx,sizeof.ICONDIRENTRY
mul ecx
add eax,sizeof.ICONDIR
; Скорректировать смещение данных с учетом размера заголовка
xor ebx,ebx
movzx ecx,word [res_head.idCount]
mov edi,res_data
@@:
add [edi+ICONDIRENTRY.dwImageOffset],eax
add edi,sizeof.ICONDIRENTRY
inc ebx
cmp ebx,ecx
jne @b
; Записать в файл заголовок иконки
invoke _lwrite,[hFile],res_head,eax
; Записать в файл отдельные иконки из группы
mov esi,[pGroup]
add esi,sizeof.ICONDIR
xor ebx,ebx
.loc_save_icon:
movzx eax,word[esi+GRPICONDIRENTRY.nID]
; Найти ресурс иконки
invoke FindResourceEx,[hModule],RT_ICON,eax,[wIDLanguage]
or eax,eax
jz .loc_next_save
mov [hResource],eax
; Получить размер данных
invoke SizeofResource,[hModule],eax
or eax,eax
jz .loc_next_save
mov [dSize],eax
; Загрузить ресурс
invoke LoadResource,[hModule],[hResource]
or eax,eax
jz .loc_next_save
; Получить указатель на начало данных в памяти
invoke LockResource,eax
mov [lpRes],eax
; Записать данные из ресурсов
invoke _lwrite,[hFile],[lpRes],[dSize]
.loc_next_save:
add esi,sizeof.GRPICONDIRENTRY
inc ebx
cmp ebx,[dGIconNum]
jb .loc_save_icon
invoke _lclose,[hFile]
.loc_next:
popa
mov eax,FALSE
ret
endp

Как и в предыдущем случае, подробно поясню, как и что тут делается. Проверка корректности группы выполняется почти так же, как и в случае с одиночными иконками, за исключением дополнительной проверки на максимально возможное количество иконок. А вот дальнейшая обработка выполняется в несколько этапов: сперва формируется полный заголовок мультииконки, затем к ней дописывается графическая информация всех доступных иконок. При формировании заголовка мультииконки, поля dwImageOffset в структурах ICONDIRENTRY первоначально формируются только с учетом размеров графических данных иконок, так как мы не знаем, какой размер заголовка получится в итоге. После формирования заголовка к этим значениям прибавляется размер полученного заголовка. Память под заголовок приходится резервировать заранее, поэтому и добавлена проверка на максимально возможное количество иконок, в моем случае это 128. Зато не надо выполнять проверку на PNG, они обрабатываются точно так же, как и обычные иконки. Почему нельзя просто скопировать всю информацию из GRPICONDIRENTRY в ICONDIRENTRY? Даже если мы узнаем количество иконок из поля idCount заголовка группы, это ни в коем случае не гарантирует, что все они доступны и могут быть загружены из ресурсов. Это утверждение справедливо, например, для упакованных файлов. Именно поэтому сперва выполняется проверка доступности всех ресурсов, и в мультииконку попадают только те, которые фактически присутствуют в исходном файле.

При необходимости все приведенные выше функции можно легко модифицировать, чтобы извлекать не только первую иконку, но и все иконки из файла. А взяв за основу этот код, также можно сделать собственный экстрактор ресурсов типа Resource Ripper. На этом тему работы с иконками исполняемых файлов считаю полностью раскрытой.

В приложении примеры программ с исходными текстами. Одна из них извлекает иконки из ресурсов исполняемого файла в отдельные файлы, а вторая создает файл с мультииконкой.

Примеры программ с исходными текстами (FASM)

Extract.Icons.Demo.zip (33,638 bytes)

Просмотров: 2534 | Комментариев: 4

Метки: Assembler, иконки

Внимание! Статья опубликована больше года назад, информация могла устареть!

Добавить комментарий

Заполните форму для добавления комментария

Если программист в девять утра уже на работе, значит он там же и ночевал

Главная страница Web-мастеру и не только Образ мышления: Assembler Мои программы Software Темная сторона Силы Обзоры техники А еще я туда ем! Жизнь в оффлайне Всякая всячина

Карта сайта Ссылки Обратная связь Правила сайта Настройки сайта RSS-канал

Материалы, опубликованные на этом сайте, не рекомендуются к просмотру лицам в возрасте до 16 лет без присутствия взрослых.

Метки статей

Свернуть

Вам помог этот сайт?

Поблагодарили 35,693 раза

День памяти крымчаков и евреев Крыма – жертв нацизма

Международный день танго

Нашли на сайте орфографическую ошибку? Выделите ее мышкой и нажмите

Ctrl

Enter

Буду очень благодарен, если размеcтите мою кнопочку:

<a href="https://www.manhunter.ru" target="_blank"><img src="https://www.manhunter.ru/images/button.gif" alt="Личный блог ManHunter'а" title="Личный блог ManHunter'а" width="88" height="31" /></a>

$Яндекс тИЦ: {YANDEX_TIC}$

Яндекс ИКС: 360

Сейчас я слушаю

---

- автообновление

Powered by PCL's Speckled Band Engine 0.2 RC3
© ManHunter / PCL, 2008-2024
При использовании материалов ссылка на сайт обязательна
Время генерации: 0.08 сек. / MySQL: 2 (0.0079 сек.) / Память: 4.5 Mb

	2024 - ДЕКАБРЬ
Пн	Вт	Ср	Чт	Пт	Сб	Вс
						1
2	3	4	5	6	7	8
9	10	11	12	13	14	15
16	17	18	19	20	21	22
23	24	25	26	27	28	29
30	31

Извлечение главной иконки из исполняемого файла

Комментарии

Добавить комментарий