Обработка перетаскивания ссылок в окно приложения

16.04.2019 | Категория: Образ мышления: Assembler | Автор: ManHunter

Обработка перетаскивания ссылок в окно приложения

С перетаскиванием файлов в окно приложения мы уже давно разобрались, это реализуется несложно. Теперь давайте разберем более интересную задачу, а именно перетаскивание в окно приложения ссылок или текста из браузеров, текстовых редакторов и других программ.

Делается это средствами интерфейсов OLE (Object Linking and Embedding). Но сперва нам понадобится несколько структур, которых, как вы уже догадались, в FASM изначально нет.

Code (Assembler) : Убрать нумерацию

; Интерфейс IDropTarget
struct IDropTargetStruct
QueryInterface dd ?
AddRef dd ?
Release dd ?
DragEnter dd ?
DragOver dd ?
DragLeave dd ?
Drop dd ?
refcount dd ?
ends
; Интерфейс IDropTarget
struct IDataObjectStruct
QueryInterface dd ?
AddRef dd ?
Release dd ?
GetData dd ?
GetDataHere dd ?
QueryGetData dd ?
GetCanonicalFormatEtc dd ?
SetData dd ?
EnumFormatEtc dd ?
DAdvise dd ?
DUnadvise dd ?
EnumDAdvise dd ?
refcount dd ?
ends
; Структуры, используемые для получения переданных строк
struct STGMEDIUM
tymed dd ?
hGlobal dd ?
pUnkForRelease dd ?
ends
struct FORMATETC
cfFormat dd ?
lptd dd ?
dwAspect dd ?
lindex dd ?
tymed dd ?
ends

При создании окна, которое должно обрабатывать перетаскивание ссылок, первым делом надо инициализировать OLE и заполнить ссылки на методы интерфейса IDropTarget, сами функции вы увидите чуть ниже. Когда все параметры будут заполнены, функцией RegisterDragDrop назначается захват перетаскивания данных нужному окну.

Code (Assembler) : Убрать нумерацию

wminitdialog:
; Инициализация OLE
invoke OleInitialize,NULL
; Настроить структуру IDropTarget для окна
mov [IDropTarget.QueryInterface],IDropTarget_QueryInterface
mov [IDropTarget.AddRef],IDropTarget_AddRef
mov [IDropTarget.Release],IDropTarget_Release
mov [IDropTarget.DragEnter],IDropTarget_DragEnter
mov [IDropTarget.DragOver],IDropTarget_DragOver
mov [IDropTarget.DragLeave],IDropTarget_DragLeave
mov [IDropTarget.Drop],IDropTarget_Drop
; Разрешить окну принимать объекты
mov [pDropTarget],IDropTarget
invoke RegisterDragDrop,[hwnddlg],pDropTarget

При закрытии окна или при завершении работы приложения надо освободить захват и разорвать соединение с OLE.

Code (Assembler) : Убрать нумерацию

wmclose:
; Освободить захват перетаскивания
invoke RevokeDragDrop,[hwnddlg]
invoke OleUninitialize

Теперь основное - реализация методов интерфейса. Я оставил только минимально необходимый код для обработки. Метод DragEnter активируется, когда курсор с захваченными данными из окна другого приложения переходит на окно нашего приложения. На этом этапе уже можно проверить, что за данные нам передают, а на основании этого принять решение, будем ли мы их обрабатывать или не будем. Метод Drop, соответственно, отвечает за обработку броска данных на окно. Именно в этом методе наше приложение должно выполнять все запланированные действия с полученной строкой.

Code (Assembler) : Убрать нумерацию

; Строка названия формата, который будет обрабатывать окно приложения
CFSTR_INETURL du 'UniformResourceLocatorW',0

Code (Assembler) : Убрать нумерацию

proc IDropTarget_QueryInterface pthis:DWORD, iid:DWORD, ppvObject:DWORD
; S_OK
xor eax,eax
ret
endp
proc IDropTarget_AddRef pthis:DWORD
lea eax,[pthis]
inc [eax+IDropTargetStruct.refcount]
mov eax,[eax+IDropTargetStruct.refcount]
ret
endp
proc IDropTarget_Release pthis:DWORD
lea eax,[pthis]
dec [eax+IDropTargetStruct.refcount]
mov eax,[eax+IDropTargetStruct.refcount]
ret
endp
;---------------------------------------------------------
; Метод DragEnter - курсор заходит на форму
;---------------------------------------------------------
proc IDropTarget_DragEnter pthis:DWORD,lpDataObject:DWORD,grfKeyState:DWORD,\
pt.x:DWORD,pt.y:DWORD,lpdwEffect:DWORD
locals
medium STGMEDIUM
fmte FORMATETC
endl
push ebx esi
; DROPEFFECT_MOVE
lea eax,[lpdwEffect]
mov dword [eax],2
; Проверить перетаскиваемую информацию на соответствие
; формату ссылки
lea eax,[medium]
push eax
lea ebx,[fmte]
invoke RegisterClipboardFormat,CFSTR_INETURL
mov [ebx+FORMATETC.cfFormat],eax
mov [ebx+FORMATETC.lptd],NULL
mov [ebx+FORMATETC.dwAspect],1
mov [ebx+FORMATETC.lindex],-1
mov [ebx+FORMATETC.tymed],1
push ebx
mov esi,[lpDataObject]
mov eax,[esi]
stdcall [eax+IDataObjectStruct.GetData],esi
or eax,eax
jz @f
; Перетаскиваемые данные не соответствуют формату
; E_INVALIDARG
mov eax,80070057h
@@:
pop esi ebx
ret
endp
;---------------------------------------------------------
; Метод DragOver - курсор перемещается над формой
;---------------------------------------------------------
proc IDropTarget_DragOver pthis:DWORD,grfKeyState:DWORD,\
pt.x:DWORD,pt.y:DWORD,lpdwEffect:DWORD
; DROPEFFECT_MOVE
lea eax,[lpdwEffect]
mov dword [eax],2
; S_OK
xor eax,eax
ret
endp
;---------------------------------------------------------
; Метод DragLeave - курсор покинул форму
;---------------------------------------------------------
proc IDropTarget_DragLeave pthis:DWORD
; S_OK
xor eax,eax
ret
endp
;---------------------------------------------------------
; Метод Drop - данные сброшены на форму
;---------------------------------------------------------
proc IDropTarget_Drop pthis:DWORD,lpDataObject:DWORD,grfKeyState:DWORD,\
pt.x:DWORD,pt.y:DWORD,lpdwEffect:DWORD
locals
medium STGMEDIUM
fmte FORMATETC
endl
pusha
; DROPEFFECT_MOVE
lea eax,[lpdwEffect]
mov dword [eax],2
lea eax,[medium]
push eax
lea ebx,[fmte]
invoke RegisterClipboardFormat,CFSTR_INETURL
mov [ebx+FORMATETC.cfFormat],eax
mov [ebx+FORMATETC.lptd],NULL
mov [ebx+FORMATETC.dwAspect],1
mov [ebx+FORMATETC.lindex],-1
mov [ebx+FORMATETC.tymed],1
push ebx
mov esi,[lpDataObject]
mov eax,[esi]
stdcall [eax+IDataObjectStruct.GetData],esi
lea eax,[medium]
mov eax,[eax+STGMEDIUM.hGlobal]
mov eax,[eax]
; EAX - указатель на переданную строку
;---------------------------------------------
; действия с переданной строкой
;---------------------------------------------
popa
; S_OK
xor eax,eax
ret
endp

Если окно должно принимать через drag'n'drop не только ссылки, а вообще любую текстовую информацию, то надо будет немного модифицировать методы DragEnter и Drop. В этом случае больше не надо проверять формат данных при заходе курсора и при броске данных на окно. Остальные методы остаются без изменений.

Code (Assembler) : Убрать нумерацию

;---------------------------------------------------------
; Метод DragEnter - курсор заходит на форму
;---------------------------------------------------------
proc IDropTarget_DragEnter pthis:DWORD,lpDataObject:DWORD,grfKeyState:DWORD,\
pt.x:DWORD,pt.y:DWORD,lpdwEffect:DWORD
; DROPEFFECT_MOVE
lea eax,[lpdwEffect]
mov dword [eax],2
; S_OK
xor eax,eax
ret
endp
;---------------------------------------------------------
; Метод Drop - данные сброшены на форму
;---------------------------------------------------------
proc IDropTarget_Drop pthis:DWORD,lpDataObject:DWORD,grfKeyState:DWORD,\
pt.x:DWORD,pt.y:DWORD,lpdwEffect:DWORD
locals
medium STGMEDIUM
fmte FORMATETC
endl
pusha
; DROPEFFECT_MOVE
lea eax,[lpdwEffect]
mov dword [eax],2
lea eax,[medium]
push eax
lea eax,[fmte]
mov [eax+FORMATETC.cfFormat],0Dh
mov [eax+FORMATETC.lptd],NULL
mov [eax+FORMATETC.dwAspect],1
mov [eax+FORMATETC.lindex],-1
mov [eax+FORMATETC.tymed],1
push eax
mov esi,[lpDataObject]
mov eax,[esi]
stdcall [eax+IDataObjectStruct.GetData],esi
lea eax,[medium]
mov eax,[eax+STGMEDIUM.hGlobal]
mov eax,[eax]
; EAX - указатель на переданную строку
;---------------------------------------------
; действия с переданной строкой
;---------------------------------------------
popa
; S_OK
xor eax,eax
ret
endp

Этот способ передачи данных окну приложения не поддерживает передачу файлов, ее надо будет реализовывать отдельно, как указано в начале статьи. Если к этому добавить еще и обработку параметров командной строки, то приложение станет по-настоящему "всеядным".

В приложении примеры программ с исходными текстами, одна из которых позволяет перетаскивать в свое окно только ссылки, а вторая принимает любые строковые данные из приложений.

Примеры программ с исходными текстами (FASM)

Drag.n.Drop.URL.Data.Demo.zip (6,349 bytes)

Просмотров: 1865 | Комментариев: 0

Метки: Assembler, окна, COM

Внимание! Статья опубликована больше года назад, информация могла устареть!

Добавить комментарий

Заполните форму для добавления комментария

Если программист в девять утра уже на работе, значит он там же и ночевал

Главная страница Web-мастеру и не только Образ мышления: Assembler Мои программы Software Темная сторона Силы Обзоры техники А еще я туда ем! Жизнь в оффлайне Всякая всячина

Карта сайта Ссылки Обратная связь Правила сайта Настройки сайта RSS-канал

Материалы, опубликованные на этом сайте, не рекомендуются к просмотру лицам в возрасте до 16 лет без присутствия взрослых.

Метки статей

Свернуть

Вам помог этот сайт?

Поблагодарили 35,665 раз

День добровольца (волонтера)

День начала контрнаступления советских войск под Москвой

День онлайн-предпринимателя

День ниндзя

Нашли на сайте орфографическую ошибку? Выделите ее мышкой и нажмите

Ctrl

Enter

Буду очень благодарен, если размеcтите мою кнопочку:

<a href="https://www.manhunter.ru" target="_blank"><img src="https://www.manhunter.ru/images/button.gif" alt="Личный блог ManHunter'а" title="Личный блог ManHunter'а" width="88" height="31" /></a>

$Яндекс тИЦ: {YANDEX_TIC}$

Яндекс ИКС: 360

Сейчас я слушаю

---

- автообновление

Powered by PCL's Speckled Band Engine 0.2 RC3
© ManHunter / PCL, 2008-2024
При использовании материалов ссылка на сайт обязательна
Время генерации: 0.07 сек. / MySQL: 2 (0.0053 сек.) / Память: 4.5 Mb

	2024 - ДЕКАБРЬ
Пн	Вт	Ср	Чт	Пт	Сб	Вс
						1
2	3	4	5	6	7	8
9	10	11	12	13	14	15
16	17	18	19	20	21	22
23	24	25	26	27	28	29
30	31

Обработка перетаскивания ссылок в окно приложения

Комментарии

Добавить комментарий