Перехват и обработка Alt+Tab

13.07.2020 | Категория: Образ мышления: Assembler | Автор: ManHunter

Сегодня поэкспериментируем с системными событиями. Это очень мощный и интересный инструмент, с помощью которого можно оперативно реагировать на события до того момента, как они дойдут до приложения. В качестве примера будем перехватывать окно переключения процессов, которое появляется при нажатии комбинации Alt+Tab, а также обрабатывать выбор элементов в этом окне. Начнем с описания нужных нам констант.

Code (Assembler) : Убрать нумерацию

EVENT_SYSTEM_SWITCHSTART = 0x0014
EVENT_SYSTEM_SWITCHEND = 0x0015
EVENT_OBJECT_FOCUS = 0x8005
WINEVENT_OUTOFCONTEXT = 0x0000
WINEVENT_SKIPOWNPROCESS = 0x0002

Затем при инициализации окна или где-нибудь в начале приложения при помощи функции SetWinEventHook подписываемся на системные события EVENT_SYSTEM_SWITCHSTART и EVENT_SYSTEM_SWITCHEND. Правильнее будет сказать, что на интервал всех событий с идентификаторами, расположенными между ними, включая границы. Но, поскольку они идут друг за другом, то получается, что только на эти два события.

Code (Assembler) : Убрать нумерацию

wminitdialog:
; Обнулить хэндл окна Alt+Tab
mov [hwndat],0
invoke SetWinEventHook,EVENT_SYSTEM_SWITCHSTART,EVENT_SYSTEM_SWITCHEND,\
NULL,WinEventProc,0,0,WINEVENT_OUTOFCONTEXT+WINEVENT_SKIPOWNPROCESS
mov [hook],eax

Останется только оформить обработчик событий WinEventProc. Для большей универсальности он будет также отвечать за обработку выбора элементов в окне Alt+Tab.

Логика обработчика следующая. При наступлении события EVENT_SYSTEM_SWITCHSTART (открытие окна Alt+Tab) устанавливается обработчик события EVENT_OBJECT_FOCUS, то есть переключение между элементами окна. Это событие срабатывает при перемещении переключателя между запущенными процессами, но обрабатываться будет только когда окно Alt+Tab активно. При наступлении события EVENT_SYSTEM_SWITCHEND (окончание выбора) обработчик переключения сбрасывается. Соответственно, на каждое из этих трех событий ваше приложение может каким-то образом реагировать.

Code (Assembler) : Убрать нумерацию

proc WinEventProc hWinEventHook:DWORD, event:DWORD, hwnd:DWORD,\
idObject:DWORD, idChild:DWORD, idEventThread:DWORD,\
dwmsEventTime:DWORD
pusha
; Начало переключения
cmp [event],EVENT_SYSTEM_SWITCHSTART
jne @f
; Окно Alt-Tab уже открыто?
cmp [hwndat],0
jne .loc_ret
mov eax,[hwnd]
mov [hwndat],eax
; Установить обработчик переключения элементов
invoke SetWinEventHook,EVENT_OBJECT_FOCUS,EVENT_OBJECT_FOCUS,NULL,\
WinEventProc,0,0,WINEVENT_OUTOFCONTEXT+WINEVENT_SKIPOWNPROCESS
mov [focus],eax
; Действие при начале переключения
...
...
jmp .loc_ret
@@:
; Смена фокуса на элементе
cmp [event],EVENT_OBJECT_FOCUS
jne @f
; Событие произошло в окне Alt+Tab?
mov eax,[hwnd]
cmp [hwndat],eax
jne .loc_ret
; Действие при переключении
...
...
jmp .loc_ret
@@:
; Завершение переключения
cmp [event],EVENT_SYSTEM_SWITCHEND
jne .loc_ret
; Окно Alt-Tab еще открыто?
cmp [hwndat],0
je .loc_ret
; Снять обработчик переключения элементов
invoke UnhookWinEvent,[focus]
mov [hwndat],0
mov [focus],0
; Действие при завершении
...
...
.loc_ret:
popa
ret
endp

Зная хэндл окна Alt+Tab, после создания можно творить с ним всякие разные штуки, например, изменить визуальный стиль и размер, убрать Aero-эффекты, добавить иконку, поменять текст в заголовке или еще что-нибудь. Но главная прелесть, что при выборе элемента мы можем получить информацию о нем. Делается это при помощи COM-объекта IAccessible. Для этого придется описать его интерфейс и еще несколько структур.

Code (Assembler) : Убрать нумерацию

struct DECIMAL
wReserved dw ?
union
struct
scale db ?
sign db ?
ends
signscale dw ?
ends
Hi32 dd ?
union
struct
Lo32 dd ?
Mid32 dd ?
ends
Lo64 dq ?
ends
ends
struct VARIANT
union
struct
vt dw ?
wReserved rw 3
union
llVal dq ?
lVal dd ?
iVal dw ?
bVal db ?
ends
ends
decVal DECIMAL
ends
ends
; Интерфейс IAccessible
struct IAccessible
QueryInterface dd ?
AddRef dd ?
Release dd ?
GetTypeInfoCount dd ?
GetTypeInfo dd ?
GetIDsOfNames dd ?
_Invoke dd ?
get_accParent dd ?
get_accChildCount dd ?
get_accChild dd ?
get_accName dd ?
get_accValue dd ?
get_accDescription dd ?
get_accRole dd ?
get_accState dd ?
get_accHelp dd ?
get_accHelpTopic dd ?
get_accKeyboardShortcut dd ?
get_accFocus dd ?
get_accSelection dd ?
get_accDefaultAction dd ?
accSelect dd ?
accLocation dd ?
accNavigate dd ?
accHitTest dd ?
accDoDefaultAction dd ?
put_accName dd ?
put_accValue dd ?
ends

При наступлении события появления окна Alt+Tab или переключения элемента, с помощью функции AccessibleObjectFromEvent получаем адрес интерфейса, через методы которого можно узнать все необходимые нам данные. Вот пример, как можно узнать общее количество элементов в окне переключения процессов, индекс выбранного элемента и его название, то есть название процесса, на котором остановился выбор.

Code (Assembler) : Убрать нумерацию

; Получить информацию о выбранном элементе
invoke AccessibleObjectFromEvent,[hwnd],[idObject],[idChild],\
pAcc,varChild
; Количество элементов в окне
mov eax,[pAcc]
mov eax,[eax]
stdcall dword [eax+IAccessible.get_accChildCount],[pAcc],tmp
; [tmp] --> всего элементов в окне
; Выбранный элемент
mov eax,[pAcc]
mov eax,[eax]
stdcall dword [eax+IAccessible.get_accFocus],[pAcc],varChild
; [varChild.lVal] --> индекс выбранного элемента
; Получить название выбранного элемента
push [bstrName]
mov eax,varChild
push dword [eax+0Ch]
push dword [eax+08h]
push dword [eax+04h]
push dword [eax]
mov eax,[pAcc]
mov eax,[eax]
stdcall dword [eax+IAccessible.get_accName],[pAcc]
; [bstrName] -> указатель на указатель на строку
; Прибраться за собой
mov eax,[pAcc]
mov eax,[eax]
stdcall dword [eax+IAccessible.Release],[pAcc]

В приложении примеры программы с исходными текстами, которые обрабатывают события окна Alt+Tab, а также при появлении этого окна меняют его стиль и заголовок. Первая программа просто реагирует на события, а вторая показывает информацию о элементах окна.

Примеры программ с исходными текстами (FASM)

Alt.Tab.Hook.Demo.zip (7,697 bytes)

Просмотров: 1296 | Комментариев: 5

Метки: Assembler, окна, COM

Внимание! Статья опубликована больше года назад, информация могла устареть!

Потому что в более серьезных программах одного только факта возникновения события обычно недостаточно, нужны подробности что и как. Их можно получить через AccessibleObjectFromEvent, которая возвращает COM-объект, через который, в свою очередь, вся необходимая мякотка и извлекается. Вот для работы с этими COM-объектами как раз и вызывается CoInitialize. В моем примере этого не требуется.

morgot (23.07.2020 в 01:56):

Спасибо, пригодится.
Почему в мсдн в примере перед этой апи идет вызов CoInitialize ? Что-то не пойму, вроде можно без СОМ обойтись, или некоторые события его требуют? Как то не юзал эту функцию ни разу.

Добавить комментарий

Заполните форму для добавления комментария

Если программист в девять утра уже на работе, значит он там же и ночевал

Главная страница Web-мастеру и не только Образ мышления: Assembler Мои программы Software Темная сторона Силы Обзоры техники А еще я туда ем! Жизнь в оффлайне Всякая всячина

Карта сайта Ссылки Обратная связь Правила сайта Настройки сайта RSS-канал

Материалы, опубликованные на этом сайте, не рекомендуются к просмотру лицам в возрасте до 16 лет без присутствия взрослых.

Метки статей

Свернуть

Вам помог этот сайт?

Поблагодарили 34,351 раз

Международный день секретаря

Международный день солидарности молодежи

Всемирный день защиты лабораторных животных

Всемирная неделя иммунизации

Нашли на сайте орфографическую ошибку? Выделите ее мышкой и нажмите

Ctrl

Enter

Буду очень благодарен, если размеcтите мою кнопочку:

<a href="https://www.manhunter.ru" target="_blank"><img src="https://www.manhunter.ru/images/button.gif" alt="Личный блог ManHunter'а" title="Личный блог ManHunter'а" width="88" height="31" /></a>

$Яндекс тИЦ: {YANDEX_TIC}$

Яндекс ИКС: 380

Сейчас я слушаю

---

- автообновление

Powered by PCL's Speckled Band Engine 0.2 RC3
© ManHunter / PCL, 2008-2024
При использовании материалов ссылка на сайт обязательна
Время генерации: 0.07 сек. / MySQL: 2 (0.0088 сек.) / Память: 4.5 Mb

	2024 - АПРЕЛЬ
Пн	Вт	Ср	Чт	Пт	Сб	Вс
1	2	3	4	5	6	7
8	9	10	11	12	13	14
15	16	17	18	19	20	21
22	23	24	25	26	27	28
29	30

Перехват и обработка Alt+Tab

Комментарии

Добавить комментарий