Генератор Mersenne Twister на Ассемблере

13.06.2021 | Категория: Образ мышления: Assembler | Автор: ManHunter

Mersenne Twister (Вихрь Мерсенна) - высокоэффективный генератор псевдослучайных чисел, разработанный Makoto Matsumoto и Takuji Nishimura. К математику Марену Мерсенну название имеет отношение потому, что период генерации равняется числу 2¹⁹⁹³⁷-1, которое, в свою очередь, является числом Мерсенна. Несмотря на то, что Mersenne Twister является одним из наиболее тщательно протестированных генераторов ПСЧ из ныне существующих, а выдаваемые им последовательности проходят статистические тесты, использование Mersenne Twister в криптографии не рекомендуется без дополнительного шифрования.

Для работы генератора требуется достаточно объемная структура, в которой сохраняется текущее состояние каждого измерения.

Code (Assembler) : Убрать нумерацию

MT_SIZE = 624
PERIOD = 397
DIFF = MT_SIZE-PERIOD
struct MT_STATE
index dd ?
mt rd MT_SIZE
mt_tempered rd MT_SIZE
ends
state MT_STATE

Сам генератор состоит из двух функций - инициализация и генерация. В принципе, можно добавить генерацию случайного числа в заданном интервале, но тут я этого делать не стал, можете посмотреть реализацию в других генераторах.

При инициализации надо передать начальный параметр, его можно получить, например, при помощи команды RDTSC, функции GetTickCount или чего-нибудь подобного.

Code (Assembler) : Убрать нумерацию

;---------------------------------------------
; Инициализация генератора случайных чисел
; stdcall mt_srand,seed
;---------------------------------------------
proc mt_srand dValue:DWORD
pusha
mov [state.index],MT_SIZE
mov eax,[dValue]
mov [state.mt],eax
mov ecx,1
@@:
mov eax,[state.mt+ecx*4-4]
mov ebx,eax
shr ebx,30
xor eax,ebx
xor edx,edx
mov ebx,0x6C078965
mul ebx
add eax,ecx
mov [state.mt+ecx*4],eax
inc ecx
cmp ecx,MT_SIZE
jb @b
popa
ret
endp

Следующая функция возвращает случайное число. Никаких входных параметров не предусмотрено, на выходе в регистре EAX сгенерированное число.

Code (Assembler) : Убрать нумерацию

;---------------------------------------------
; Получить случайное число
; stdcall mt_rand
; на выходе EAX - случайное число
;---------------------------------------------
proc mt_rand
pusha
cmp [state.index],MT_SIZE
jne .loc_ret
xor ecx,ecx
.loc_loop:
mov eax,[state.mt+ecx*4]
and eax,0x80000000
mov ebx,[state.mt+ecx*4+4]
and ebx,0x7FFFFFFF
or eax,ebx
mov ebx,eax
shl ebx,31
shr ebx,31
and ebx,0x9908B0DF
shr eax,1
xor eax,ebx
mov ebx,[state.mt+ecx*4+PERIOD*4]
cmp ecx,DIFF
jb @f
mov ebx,[state.mt+ecx*4-DIFF*4]
@@:
xor eax,ebx
mov [state.mt+ecx*4],eax
inc ecx
cmp ecx,(MT_SIZE-1)
jb .loc_loop
mov eax,[state.mt+(MT_SIZE-1)*4]
and eax,0x80000000
mov ebx,[state.mt]
and ebx,0x7FFFFFFF
or eax,ebx
mov ebx,eax
shl ebx,31
shr ebx,31
and ebx,0x9908B0DF
shr eax,1
xor eax,ebx
xor eax,[state.mt+(PERIOD-1)*4]
mov [state.mt+(MT_SIZE-1)*4],eax
; temper
xor ecx,ecx
.loc_temper:
mov eax,[state.mt+ecx*4]
mov ebx,eax
shr ebx,11
xor eax,ebx
mov ebx,eax
shl ebx,7
and ebx,0x9D2C5680
xor eax,ebx
mov ebx,eax
shl ebx,15
and ebx,0xEFC60000
xor eax,ebx
mov ebx,eax
shr ebx,18
xor eax,ebx
mov [state.mt_tempered+ecx*4],eax
inc ecx
cmp ecx,MT_SIZE
jb .loc_temper
mov [state.index],0
.loc_ret:
inc [state.index]
mov eax,[state.index]
mov eax,[state.mt_tempered+eax*4]
mov [esp+28],eax
popa
ret
endp

В приложении пример программы с исходным текстом, которая генерирует псевдослучайные числа с использованием Mersenne Twister.

Пример программы с исходным текстом (FASM)

Mersenne.Twister.Demo.zip (3,258 bytes)

Просмотров: 1157 | Комментариев: 1

Метки: Assembler, генератор ПСЧ

Внимание! Статья опубликована больше года назад, информация могла устареть!

ГОСТ-а на алгоритм нету, потому все реализации выдают разные результаты.
Попалась когда-то игра на .net с обфускацией, гугление 0x6C078965 привело на Mersenne Twister, первая часть ключа была как init, а все последующие части ключа как word от random.next. Испытал более десятка реализаций на разных языках и нифига общего, результаты везде разные.

Добавить комментарий

Заполните форму для добавления комментария

Если программист в девять утра уже на работе, значит он там же и ночевал

Главная страница Web-мастеру и не только Образ мышления: Assembler Мои программы Software Темная сторона Силы Обзоры техники А еще я туда ем! Жизнь в оффлайне Всякая всячина

Карта сайта Ссылки Обратная связь Правила сайта Настройки сайта RSS-канал

Материалы, опубликованные на этом сайте, не рекомендуются к просмотру лицам в возрасте до 16 лет без присутствия взрослых.

Метки статей

Свернуть

Вам помог этот сайт?

Поблагодарили 35,982 раза

День штурмана Военно-Морского Флота России

День российского студенчества

Нашли на сайте орфографическую ошибку? Выделите ее мышкой и нажмите

Ctrl

Enter

Буду очень благодарен, если размеcтите мою кнопочку:

<a href="https://www.manhunter.ru" target="_blank"><img src="https://www.manhunter.ru/images/button.gif" alt="Личный блог ManHunter'а" title="Личный блог ManHunter'а" width="88" height="31" /></a>

$Яндекс тИЦ: {YANDEX_TIC}$

Яндекс ИКС: 360

Сейчас я слушаю

---

- автообновление

Powered by PCL's Speckled Band Engine 0.2 RC3
© ManHunter / PCL, 2008-2025
При использовании материалов ссылка на сайт обязательна
Время генерации: 0.07 сек. / MySQL: 2 (0.0041 сек.) / Память: 4.5 Mb

	2025 - ЯНВАРЬ
Пн	Вт	Ср	Чт	Пт	Сб	Вс
		1	2	3	4	5
6	7	8	9	10	11	12
13	14	15	16	17	18	19
20	21	22	23	24	25	26
27	28	29	30	31

Генератор Mersenne Twister на Ассемблере

Комментарии

Добавить комментарий