Как получить путь из символической ссылки

24.10.2022 | Категория: Образ мышления: Assembler | Автор: ManHunter

Начиная с Windows Vista, в системе появились так называемые символические ссылки, специальные файлы, в которых вместо каких-либо данных содержится путь к другому файлу или каталогу, открываемому при обращении к этой ссылке. Это позволяет, например, иметь для одного и того же файла сразу несколько разных имен.

Чтобы получить целевой путь, на который указывает символическая ссылка, есть несколько методов. Обычно в этих ваших интернетах рекомендуют сложный путь через использование функции DeviceIoControl. Штука интересная, с нее и начнем. Но сперва пачка структур и констант, которые нам понадобятся для работы.

Code (Assembler) : Убрать нумерацию

struct SymbolicLinkReparseBuffer
SubstituteNameOffset dw ?
SubstituteNameLength dw ?
PrintNameOffset dw ?
PrintNameLength dw ?
Flags dd ?
PathBuffer rw MAX_PATH*2
ends
struct MountPointReparseBuffer
SubstituteNameOffset dw ?
SubstituteNameLength dw ?
PrintNameOffset dw ?
PrintNameLength dw ?
PathBuffer rw MAX_PATH*2
ends
struct GenericReparseBuffer
DataBuffer db ?
ends
struct REPARSE_DATA_BUFFER
ReparseTag dd ?
ReparseDataLength dw ?
Reserved dw ?
union
SymbolicLink SymbolicLinkReparseBuffer
MountPoint MountPointReparseBuffer
Generic GenericReparseBuffer
ends
ends
FSCTL_GET_REPARSE_POINT = 0x000900A8
FILE_FLAG_BACKUP_SEMANTICS = 0x02000000
FILE_FLAG_OPEN_REPARSE_POINT = 0x00200000
IO_REPARSE_TAG_MOUNT_POINT = 0xA0000003
IO_REPARSE_TAG_SYMLINK = 0xA000000C

Первым делом для вашего процесса надо активировать привилегию SeBackupPrivilege. Это мы уже делали, тут ничего нового нет. В оригинале эта привилегия нужна для выполнения резервного копирования файлов, а по факту она предоставляет доступ на чтение для любого файла, независимо от списка контроля доступа. Именно это нам требуется для получения информации из символической ссылки.

Получив привилегии, с помощью функции CreateFile открываем символическую ссылку с указанием флагов FILE_FLAG_BACKUP_SEMANTICS и FILE_FLAG_OPEN_REPARSE_POINT.

Code (Assembler) : Убрать нумерацию

; Открыть файл символической ссылки
invoke CreateFile,dir_name,\
0,FILE_SHARE_READ,\
NULL,OPEN_EXISTING,\
FILE_FLAG_BACKUP_SEMANTICS+FILE_FLAG_OPEN_REPARSE_POINT,\
NULL
cmp eax,INVALID_HANDLE_VALUE
je loc_exit
; Сохранить хэндл
mov [hDirectory],eax
; Зарезервировать память
invoke GlobalAlloc,GMEM_MOVEABLE+GMEM_DDESHARE+GMEM_ZEROINIT,\
sizeof.REPARSE_DATA_BUFFER
mov [mem],eax
invoke GlobalLock,[mem]
mov [memp],eax
; Получить данные объекта
invoke DeviceIoControl,[hDirectory],\
FSCTL_GET_REPARSE_POINT,\
0,0,\
[memp],sizeof.REPARSE_DATA_BUFFER,\
tmp,NULL
or eax,eax
jz loc_close
; Проверить тип данных
mov eax,[memp]
mov ecx,[eax+REPARSE_DATA_BUFFER.ReparseTag]
; Выбрать источник строки на основании типа
cmp ecx,IO_REPARSE_TAG_MOUNT_POINT
jne @f
lea ebx,[eax+REPARSE_DATA_BUFFER.MountPoint.PathBuffer]
jmp loc_message
@@:
cmp ecx,IO_REPARSE_TAG_SYMLINK
jne loc_close
lea ebx,[eax+REPARSE_DATA_BUFFER.SymbolicLink.PathBuffer]
loc_message:
...
...
; EBX -> строка с названием целевого пути
...
...
loc_close:
; Прибраться за собой
invoke CloseHandle,[hDirectory]
; Освободить память
invoke GlobalUnlock,[mem]
invoke GlobalFree,[mem]

Получив хэндл символической ссылки, с запасом резервируем память под структуру REPARSE_DATA_BUFFER и заполняем ее данными при помощи функции DeviceIoControl с кодом операции FSCTL_GET_REPARSE_POINT. В первом ее поле ReparseTag записан тип полученных данных, это может быть точка монтирования или символическая ссылка. В зависимости от этого получаем строку с целевым путем из соответствующей структуры. Полученный путь имеет вид типа "\??\С:\Users", это надо учитывать при дальнейшей обработке.

Со сложным путем закончили, теперь рассмотрим простой и приятный. Вместе с символическими ссылками в Windows Vista появилась функция GetFinalPathNameByHandle, с помощью которой также можно получить путь символической ссылки. Об обратной совместимости в этом случае можно не заботиться, так как и технология, и инструментарий, все появилось одновременно.

Code (Assembler) : Убрать нумерацию

FILE_READ_EA = 0x0008
FILE_FLAG_BACKUP_SEMANTICS = 0x02000000

Прописав недостающие константы, сразу переходим к коду. Никаких предварительных действий типа повышения привилегий не требуется. Небольшое отличие от предыдущего открытия файла заключается в типе доступа FILE_READ_EA (чтение расширенных атрибутов файла) и единственном флаге FILE_FLAG_BACKUP_SEMANTICS.

Code (Assembler) : Убрать нумерацию

; Открыть файл символической ссылки
invoke CreateFile,dir_name,\
FILE_READ_EA,\
FILE_SHARE_READ+FILE_SHARE_WRITE,\
NULL,OPEN_EXISTING,\
FILE_FLAG_BACKUP_SEMANTICS,\
NULL
cmp eax,INVALID_HANDLE_VALUE
je loc_exit
; Сохранить хэндл
mov [hDirectory],eax
; Зарезервировать память
invoke GlobalAlloc,GMEM_MOVEABLE+GMEM_DDESHARE+GMEM_ZEROINIT,\
MAX_PATH*2
mov [mem],eax
invoke GlobalLock,[mem]
mov [memp],eax
; Получить целевой объект символической ссылки
invoke GetFinalPathNameByHandle,[hDirectory],[memp],MAX_PATH,0
...
...
; [memp] -> строка с названием целевого пути
...
...
; Прибраться за собой
invoke CloseHandle,[hDirectory]
; Освободить память
invoke GlobalUnlock,[mem]
invoke GlobalFree,[mem]

Дальше резервируем память нужного объема для получения пути и вызываем функцию GetFinalPathNameByHandle, как показано в коде. Полученный путь, как и в первом примере, также дополняется префиксом типа "\??\С:\Users". Вот и вся магия.

В приложении примеры программ с исходными текстами, которые определяют путь из символической ссылки двумя разными способами.

Примеры программ с исходными текстами (FASM)

Get.Symlink.Target.zip (4,458 bytes)

Просмотров: 580 | Комментариев: 2

Метки: Assembler

Внимание! Статья опубликована больше года назад, информация могла устареть!

Добавить комментарий

Заполните форму для добавления комментария

Если программист в девять утра уже на работе, значит он там же и ночевал

Главная страница Web-мастеру и не только Образ мышления: Assembler Мои программы Software Темная сторона Силы Обзоры техники А еще я туда ем! Жизнь в оффлайне Всякая всячина

Карта сайта Ссылки Обратная связь Правила сайта Настройки сайта RSS-канал

Материалы, опубликованные на этом сайте, не рекомендуются к просмотру лицам в возрасте до 16 лет без присутствия взрослых.

Метки статей

Свернуть

Вам помог этот сайт?

Поблагодарили 35,663 раза

День информатики

День заказов подарков и написания писем Деду Морозу

Нашли на сайте орфографическую ошибку? Выделите ее мышкой и нажмите

Ctrl

Enter

Буду очень благодарен, если размеcтите мою кнопочку:

<a href="https://www.manhunter.ru" target="_blank"><img src="https://www.manhunter.ru/images/button.gif" alt="Личный блог ManHunter'а" title="Личный блог ManHunter'а" width="88" height="31" /></a>

$Яндекс тИЦ: {YANDEX_TIC}$

Яндекс ИКС: 360

Сейчас я слушаю

---

- автообновление

Powered by PCL's Speckled Band Engine 0.2 RC3
© ManHunter / PCL, 2008-2024
При использовании материалов ссылка на сайт обязательна
Время генерации: 4.03 сек. / MySQL: 2 (3.9592 сек.) / Память: 4.5 Mb

	2024 - ДЕКАБРЬ
Пн	Вт	Ср	Чт	Пт	Сб	Вс
						1
2	3	4	5	6	7	8
9	10	11	12	13	14	15
16	17	18	19	20	21	22
23	24	25	26	27	28	29
30	31

Как получить путь из символической ссылки

Комментарии

Добавить комментарий