Мониторинг активности HDD на Ассемблере

09.01.2023 | Категория: Образ мышления: Assembler | Автор: ManHunter

В качестве предисловия коротенький анекдот из времен MS-DOS: "- Висим... - Не висим. - Висим! - Не висим, говорю - диском дpыгает." И действительно, активность жесткого диска, выражавшаяся в моргании соответствующего индикатора на корпусе, говорила о работе процесса, просто надо было подождать. Но иногда такие индикаторы отсутствовали или системник стоял в таком месте, что их не было видно. В этих случаях приходилось решать задачу различными программами, которые отображали активность жесткого диска как-нибудь иначе, например, морганием светодиода ScrollLock на клавиатуре.

Вот и мне захотелось сделать что-нибудь подобное. Естественно, на Ассемблере. Для начала некоторые данные, о которых не знает FASM.

Code (Assembler) : Убрать нумерацию

struct DISK_PERFORMANCE
BytesRead dq ?
BytesWritten dq ?
ReadTime dq ?
WriteTime dq ?
IdleTime dq ?
ReadCount dd ?
WriteCount dd ?
QueueDepth dd ?
SplitCount dd ?
QueryTime dd ?
StorageDeviceNumber dd ?
StorageManagerName rd 8
ends
IOCTL_DISK_PERFORMANCE = 0x70020

Дальше немного теории. Текущее состояние жесткого диска можно узнать при помощи функции DeviceIoControl с параметром IOCTL_DISK_PERFORMANCE. При удачном выполнении операции будет возвращена заполненная структура DISK_PERFORMANCE. В документации написано, что в полях ReadTime и WriteTime передаются счетчики времени, необходимые для выполнения операций чтения или записи. Сохранив текущее значение этих счетчиков и периодически сравнивая текущие значения с сохраненными данными, можно смело утверждать о выполнении операции жестким диском. И, соответственно, каким-то образом оповещать об этом пользователя.

А вот и сам код. Он максимально упрощен и заточен на мониторинг самого первого диска в системе. В качестве индикаторов используются обычные текстовые поля.

Code (Assembler) : Убрать нумерацию

szDrive du '\\.\PhysicalDrive0',0
...
; Открыть диск для работы
invoke CreateFile,szDrive,0,0,0,OPEN_EXISTING,0,0
cmp eax,-1
je .wmclose
mov [hhd],eax
; Инициализация времени чтения и записи
mov dword [read_time],0
mov dword [read_time+4],0
mov dword [write_time],0
mov dword [write_time+4],0

После инициализации надо запустить периодический опрос состояния. Это можно сделать по таймеру в оконном приложении или в отдельном потоке, как вам привычнее.

Code (Assembler) : Убрать нумерацию

; Получить информацию о диске
invoke DeviceIoControl,[hhd],IOCTL_DISK_PERFORMANCE,\
0,0,perf,sizeof.DISK_PERFORMANCE,tmp,0
.chk_read:
; Время последнего чтения отличается?
mov eax,dword[perf.ReadTime]
cmp dword[read_time],eax
jne @f
mov eax,dword[perf.ReadTime+4]
cmp dword[read_time+4],eax
jne @f
; Выключить индикатор
mov ebx,FALSE
jmp .set_read
@@:
; Актуализировать время чтения
mov eax,dword[perf.ReadTime]
mov dword[read_time],eax
mov eax,dword[perf.ReadTime+4]
mov dword[read_time+4],eax
; Включить индикатор
mov ebx,TRUE
.set_read:
; Включить или выключить индикатор
invoke GetDlgItem,[hwnddlg],ID_READ
invoke EnableWindow,eax,ebx
.chk_write:
; Время последней записи отличается?
mov eax,dword[perf.WriteTime]
cmp dword[write_time],eax
jne @f
mov eax,dword[perf.WriteTime+4]
cmp dword[write_time+4],eax
jne @f
; Выключить индикатор
mov ebx,FALSE
jmp .set_write
@@:
; Актуализировать время записи
mov eax,dword[perf.WriteTime]
mov dword[write_time],eax
mov eax,dword[perf.WriteTime+4]
mov dword[write_time+4],eax
; Включить индикатор
mov ebx,TRUE
.set_write:
; Включить или выключить индикатор
invoke GetDlgItem,[hwnddlg],ID_WRITE
invoke EnableWindow,eax,ebx

Вместо включения-выключения текстовых полей можно моргать светодиодами клавиатуры, выводить иконку в трей или сообщать об активности диска любым другим удобным вам способом. Операции чтения и записи тоже не обязательно разделять, ведь обе они означают активность диска.

В приложении пример программы с исходным текстом, которая мониторит активность жесткого диска.

Пример программы с исходным текстом (FASM)

HDD.Activity.Demo.zip (2,877 bytes)

Просмотров: 662 | Комментариев: 0

Метки: Assembler, HDD

Внимание! Статья опубликована больше года назад, информация могла устареть!

Добавить комментарий

Заполните форму для добавления комментария

Если программист в девять утра уже на работе, значит он там же и ночевал

Главная страница Web-мастеру и не только Образ мышления: Assembler Мои программы Software Темная сторона Силы Обзоры техники А еще я туда ем! Жизнь в оффлайне Всякая всячина

Карта сайта Ссылки Обратная связь Правила сайта Настройки сайта RSS-канал

Материалы, опубликованные на этом сайте, не рекомендуются к просмотру лицам в возрасте до 16 лет без присутствия взрослых.

Метки статей

Свернуть

Вам помог этот сайт?

Поблагодарили 35,184 раза

Всемирный день безопасности пациентов

Нашли на сайте орфографическую ошибку? Выделите ее мышкой и нажмите

Ctrl

Enter

Буду очень благодарен, если размеcтите мою кнопочку:

<a href="https://www.manhunter.ru" target="_blank"><img src="https://www.manhunter.ru/images/button.gif" alt="Личный блог ManHunter'а" title="Личный блог ManHunter'а" width="88" height="31" /></a>

$Яндекс тИЦ: {YANDEX_TIC}$

Яндекс ИКС: 360

Сейчас я слушаю

---

- автообновление

Powered by PCL's Speckled Band Engine 0.2 RC3
© ManHunter / PCL, 2008-2024
При использовании материалов ссылка на сайт обязательна
Время генерации: 0.07 сек. / MySQL: 2 (0.0079 сек.) / Память: 4.5 Mb

	2024 - СЕНТЯБРЬ
Пн	Вт	Ср	Чт	Пт	Сб	Вс
						1
2	3	4	5	6	7	8
9	10	11	12	13	14	15
16	17	18	19	20	21	22
23	24	25	26	27	28	29
30

Мониторинг активности HDD на Ассемблере

Комментарии

Добавить комментарий