Blog. Just Blog

Устраняем косяки функций PathRemoveExtension и PathRenameExtension

Версия для печати Добавить в Избранное Отправить на E-Mail | Категория: Образ мышления: Assembler | Автор: ManHunter
В комментариях к статьям иногда проскакивают мысли, мол, зачем изобретать велосипед, если уже существуют готовые WinAPI. Ну так вот, в библиотеке shlwapi помимо кучи других полезных функций есть две функции для работы с расширениями файлов. PathRemoveExtension служит для удаления расширения из строки с путем файла, а PathRenameExtension для замены имеющегося расширения на другое. Это очень удобно в случае, когда, например, надо сгенерировать имя файла данных или файла с настройками по имени исполняемого файла. Но, к сожалению, у них есть фатальные косяки в реализации. Это проще показать на примерах. Вот удаление расширения:

c:\test\file1.txt -> PathRemoveExtension -> c:\test\file1
c:\test\file2 -> PathRemoveExtension -> c:\test\file2
c:\test\.htaccess -> PathRemoveExtension -> c:\test\
c:\test\.htaccess.bak -> PathRemoveExtension -> c:\test\.htaccess

И аналогично для замены расширения, например, на ".ini":

c:\test\file1.txt -> PathRenameExtension -> c:\test\file1.ini
c:\test\file2 -> PathRenameExtension -> c:\test\file2.ini
c:\test\.htaccess -> PathRenameExtension -> c:\test\.ini
c:\test\ -> PathRenameExtension -> c:\test\.ini
c:\test\.htaccess.bak -> PathRenameExtension -> c:\test\.htaccess.ini

Как видите, если имя файла начинается с точки и при этом файл не имеет расширения, то обе функции работают неправильно. Кроме этого, функция замены расширения дает неправильный с точки зрения логики результат, если имя файла в строке вообще отсутствует.

Когда я столкнулся с таким поведением штатных функций, пришлось написать свои реализации, которые дают ожидаемый результат.
  1. ;----------------------------------------------------------
  2. ; Удаление расширения файла из строки
  3. ;----------------------------------------------------------
  4. proc PathRemoveExtensionTrue lpszPath:DWORD
  5.         pusha
  6.  
  7.         mov     esi,[lpszPath]
  8.         invoke  lstrlen,esi
  9.         add     esi,eax
  10.         inc     esi
  11. @@:
  12.         dec     esi
  13.         cmp     esi,[lpszPath]
  14.         je      .loc_ret
  15.         cmp     byte [esi],'\'
  16.         je      .loc_ret
  17.         cmp     byte [esi],':'
  18.         je      .loc_ret
  19.         cmp     byte [esi],'.'
  20.         jne     @b
  21.         dec     esi
  22.         cmp     esi,[lpszPath]
  23.         je      .loc_ret
  24.         cmp     byte [esi],'\'
  25.         je      .loc_ret
  26.         mov     byte [esi+1],0
  27. .loc_ret:
  28.         popa
  29.         ret
  30. endp
  1. ;----------------------------------------------------------
  2. ; Замена расширения файла в строке
  3. ;----------------------------------------------------------
  4. proc PathRenameExtensionTrue lpszPath:DWORD,lpszExt:DWORD
  5.         pusha
  6.  
  7.         mov     esi,[lpszPath]
  8.         invoke  lstrlen,esi
  9.         or      eax,eax
  10.         jz      .loc_ret
  11.         add     esi,eax
  12.         cmp     byte [esi-1],'\'
  13.         je      .loc_ret
  14. @@:
  15.         dec     esi
  16.         cmp     byte [esi],'\'
  17.         je      @f
  18.         cmp     byte [esi],':'
  19.         je      @f
  20.         cmp     esi,[lpszPath]
  21.         je      @f
  22.         cmp     byte [esi],'.'
  23.         jne     @b
  24.         dec     esi
  25.         cmp     esi,[lpszPath]
  26.         je      @f
  27.         cmp     byte [esi],'\'
  28.         je      @f
  29.         cmp     byte [esi],':'
  30.         je      @f
  31.         mov     byte [esi+1],0
  32. @@:
  33.         invoke  lstrcat,[lpszPath],[lpszExt]
  34.  
  35. .loc_ret:
  36.         popa
  37.         ret
  38. endp
Параметры вызова обеих функций аналогичны системным. А вот результат отличается, на этот раз он правильный.

c:\test\file1.txt -> PathRemoveExtensionTrue -> c:\test\file1
c:\test\file2 -> PathRemoveExtensionTrue -> c:\test\file2
c:\test\.htaccess -> PathRemoveExtensionTrue -> c:\test\.htaccess
c:\test\.htaccess.bak -> PathRemoveExtensionTrue -> c:\test\.htaccess

c:\test\file1.txt -> PathRenameExtensionTrue -> c:\test\file1.ini
c:\test\file2 -> PathRenameExtensionTrue -> c:\test\file2.ini
c:\test\.htaccess -> PathRenameExtensionTrue -> c:\test\.htaccess.ini
c:\test\ -> PathRenameExtensionTrue -> c:\test\
c:\test\.htaccess.bak -> PathRenameExtensionTrue -> c:\test\.htaccess.ini

Хочешь сделать хорошо - сделай это сам. При необходимости функции можно дополнительно усилить, например, автоматически исправлять слеши или добавить проверку на их "косой" вариант.

Поделиться ссылкой ВКонтакте
Просмотров: 200 | Комментариев: 0

Метки: Assembler

Комментарии

Отзывы посетителей сайта о статье
Комментариeв нет

Добавить комментарий

Заполните форму для добавления комментария
Имя*:
Текст комментария (не более 2000 символов)*:

*Все поля обязательны для заполнения.
Комментарии, содержащие рекламу, ненормативную лексику, оскорбления и т.п., а также флуд и сообщения не по теме, будут удаляться. Нарушителям может быть заблокирован доступ к сайту.
Наверх
Powered by PCL's Speckled Band Engine 0.2 RC3
© ManHunter / PCL, 2008-2024
При использовании материалов ссылка на сайт обязательна
Время генерации: 0.08 сек. / MySQL: 3 (0.0041 сек.) / Память: 4.5 Mb
Наверх